Add Arm64 version of breakpad_getcontext for Android.

common/android/breakpad_getcontext.S

 // Copyright (c) 2012, Google Inc.
 // All rights reserved.
 //
 // Redistribution and use in source and binary forms, with or without
 // modification, are permitted provided that the following conditions are
 // met:
 //
 //     * Redistributions of source code must retain the above copyright
 // notice, this list of conditions and the following disclaimer.
 //     * Redistributions in binary form must reproduce the above
@@ skipping 16 matching lines @@
 // (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 // OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 
 // A minimalistic implementation of getcontext() to be used by
 // Google Breakpad on Android.
 
 #include "common/android/ucontext_constants.h"
 
 /* int getcontext (ucontext_t *ucp) */
 
 #ifdef __arm__

[Mark Mentovai, 2014/04/02 16:22:18]

Change to #if defined(…) to match all of the #elif defined(…)s that follow.

[rmcilroy, 2014/04/02 23:01:28]

Done.

 
   .text
   .global breakpad_getcontext
   .hidden breakpad_getcontext
   .type breakpad_getcontext, #function
   .align 0
   .fnstart
 breakpad_getcontext:
 
   /* First, save r4-r11 */
   add   r1, r0, #(MCONTEXT_GREGS_OFFSET + 4*4)
   stm   r1, {r4-r11}
 
   /* r12 is a scratch register, don't save it */
 
-  /* Save sp and lr explicitely. */
+  /* Save sp and lr explicitly. */
   /* - sp can't be stored with stmia in Thumb-2 */
   /* - STM instructions that store sp and pc are deprecated in ARM */
   str   sp, [r0, #(MCONTEXT_GREGS_OFFSET + 13*4)]
   str   lr, [r0, #(MCONTEXT_GREGS_OFFSET + 14*4)]
 
   /* Save the caller's address in 'pc' */
   str   lr, [r0, #(MCONTEXT_GREGS_OFFSET + 15*4)]
 
-  /* Save ucontext_t* pointer accross next call */
+  /* Save ucontext_t* pointer across next call */
   mov   r4, r0
 
   /* Call sigprocmask(SIG_BLOCK, NULL, &(ucontext->uc_sigmask)) */
   mov   r0, #0  /* SIG_BLOCK */
   mov   r1, #0  /* NULL */
   add   r2, r4, #UCONTEXT_SIGMASK_OFFSET
   bl    sigprocmask(PLT)
 
   /* Intentionally do not save the FPU state here. This is because on
    * Linux/ARM, one should instead use ptrace(PTRACE_GETFPREGS) or
    * ptrace(PTRACE_GETVFPREGS) to get it.
    *
    * Note that a real implementation of getcontext() would need to save
    * this here to allow setcontext()/swapcontext() to work correctly.
    */
 
   /* Restore the values of r4 and lr */
   mov   r0, r4
   ldr   lr, [r0, #(MCONTEXT_GREGS_OFFSET + 14*4)]
   ldr   r4, [r0, #(MCONTEXT_GREGS_OFFSET +  4*4)]
 
   /* Return 0 */
   mov   r0, #0
   bx    lr
 
   .fnend
   .size breakpad_getcontext, . - breakpad_getcontext
 
+#elif defined(__aarch64__)
+
+  .text
+  .global breakpad_getcontext
+  .hidden breakpad_getcontext
+  .type breakpad_getcontext, #function
+  .align 4
+  .cfi_startproc
+breakpad_getcontext:
+
+  /* The saved context will return to the getcontext() call point
+     with a return value of 0 */
+  str     xzr,      [x0, MCONTEXT_GREGS_OFFSET +  0 * REGISTER_SIZE]
+
+  stp     x18, x19, [x0, MCONTEXT_GREGS_OFFSET + 18 * REGISTER_SIZE]
+  stp     x20, x21, [x0, MCONTEXT_GREGS_OFFSET + 20 * REGISTER_SIZE]
+  stp     x22, x23, [x0, MCONTEXT_GREGS_OFFSET + 22 * REGISTER_SIZE]
+  stp     x24, x25, [x0, MCONTEXT_GREGS_OFFSET + 24 * REGISTER_SIZE]
+  stp     x26, x27, [x0, MCONTEXT_GREGS_OFFSET + 26 * REGISTER_SIZE]
+  stp     x28, x29, [x0, MCONTEXT_GREGS_OFFSET + 28 * REGISTER_SIZE]
+  str     x30,      [x0, MCONTEXT_GREGS_OFFSET + 30 * REGISTER_SIZE]
+
+  /* Place LR into the saved PC, this will ensure that when
+     switching to this saved context with setcontext() control
+     will pass back to the caller of getcontext(), we have
+     already arrange to return the appropriate return value in x0

[Mark Mentovai, 2014/04/02 16:22:18]

arranged

[rmcilroy, 2014/04/02 23:01:28]

Done.

+     above.  */
+  str     x30, [x0, MCONTEXT_PC_OFFSET]
+
+  /* Save the current SP */
+  mov     x2, sp
+  str     x2, [x0, MCONTEXT_SP_OFFSET]
+
+  /* Initialize the pstate.  */
+  str     xzr, [x0, MCONTEXT_PSTATE_OFFSET]
+
+  /* Figure out where to place the first context extension
+     block.  */
+  add     x2, x0, #MCONTEXT_EXTENSION_OFFSET
+
+  /* Write the context extension fpsimd header.  */

[rmcilroy, 2014/04/02 16:05:10]

Do we need to save the fpsimd context for aarch64?  The comment in Arm suggests
it's not required for arm, but I'm not sure for arm64, and don't know how
breakpad uses the context well enough to know if we need the fpsimd context too.
 Any idea Mark?

[Mark Mentovai, 2014/04/02 16:22:18]

rmcilroy wrote:
Breakpad won’t use it for the stack walk, but the data might still come in
handy. There have been a couple of cases in the past where having FP or SIMD
register state handy in a dump file has helped pinpoint a problem.

[rmcilroy, 2014/04/02 23:01:28]

Sounds good, I've updated exception_handler appropriately now.

+  mov     w3, #(FPSIMD_MAGIC & 0xffff)
+  movk    w3, #(FPSIMD_MAGIC >> 16), lsl #16
+  str     w3, [x2, #FPSIMD_CONTEXT_MAGIC_OFFSET]
+  mov     w3, #FPSIMD_CONTEXT_SIZE
+  str     w3, [x2, #FPSIMD_CONTEXT_SIZE_OFFSET]
+
+  /* Fill in the FP SIMD context.  */
+  add     x3, x2, #(FPSIMD_CONTEXT_VREGS_OFFSET + 8 * SIMD_REGISTER_SIZE)
+  stp     d8,  d9, [x3], #(2 * SIMD_REGISTER_SIZE)
+  stp     d10, d11, [x3], #(2 * SIMD_REGISTER_SIZE)
+  stp     d12, d13, [x3], #(2 * SIMD_REGISTER_SIZE)
+  stp     d14, d15, [x3], #(2 * SIMD_REGISTER_SIZE)
+
+  add     x3, x2, FPSIMD_CONTEXT_FPSR_OFFSET
+
+  mrs     x4, fpsr
+  str     w4, [x3]
+
+  mrs     x4, fpcr
+  str     w4, [x3, FPSIMD_CONTEXT_FPCR_OFFSET - FPSIMD_CONTEXT_FPSR_OFFSET]
+
+  /* Write the termination context extension header.  */
+  add     x2, x2, #FPSIMD_CONTEXT_SIZE
+
+  str     xzr, [x2, #FPSIMD_CONTEXT_MAGIC_OFFSET]
+  str     xzr, [x2, #FPSIMD_CONTEXT_SIZE_OFFSET]
+
+  /* Grab the signal mask */
+  /* rt_sigprocmask (SIG_BLOCK, NULL, &ucp->uc_sigmask, _NSIG8) */
+  add     x2, x0, #UCONTEXT_SIGMASK_OFFSET
+  mov     x0, #0  /* SIG_BLOCK */
+  mov     x1, #0  /* NULL */
+  mov     x3, #(_NSIG / 8)
+  mov     x8, #__NR_rt_sigprocmask
+  svc     0
+
+  /* Return x0 for success */
+  mov     x0, 0
+  ret
+
+  .cfi_endproc
+  .size breakpad_getcontext, . - breakpad_getcontext
+
 #elif defined(__i386__)
 
   .text
   .global breakpad_getcontext
   .hidden breakpad_getcontext
   .align 4
   .type breakpad_getcontext, @function
 
 breakpad_getcontext:
 
@@ skipping 32 matching lines @@
   push %ecx   /* NULL */
   push %ecx   /* SIGBLOCK == 0 on i386 */
   call sigprocmask@PLT
   addl $12, %esp
 
   movl $0, %eax
   ret
 
   .size breakpad_getcontext, . - breakpad_getcontext
 
-#elif defined(__aarch64__)
-
- // TODO(rmcilroy): Implement for arm64.
-
 #elif defined(__mips__)
 
 #if _MIPS_SIM != _ABIO32
 #error "Unsupported mips ISA. Only mips o32 is supported."
 #endif
 
 // This implementation is inspired by implementation of getcontext in glibc.
 #include <asm/asm.h>
 #include <asm/regdef.h>
 #include <asm/fpregdef.h>
@@ skipping 62 matching lines @@
   lw gp, GP_FRAME_OFFSET(sp)
   addiu sp, FRAME_SIZE
   jr ra
 
 END (breakpad_getcontext)
 
 
 #else
 #error "This file has not been ported for your CPU!"
 #endif